신규

Delphi Modbus TCP 및 RTU: 클라이언트와 서버 컴포넌트

Delphi와 C++Builder용 네이티브 Modbus TCP 및 Modbus RTU 컴포넌트. PLC, 드라이브, 전력량계, 게이트웨이를 폴링하거나, 내 데이터를 Modbus 서버로 게시할 수 있으며, 모든 워드 순서를 지원하는 타입 Float32, Int32, 문자열 헬퍼를 제공해요.

sgcWebSockets Enterprise(Delphi 및 .NET)와 All-Access, 또는 독립형 sgcIndustrial 팩에 포함.

클라이언트 둘, 서버 둘, 하나의 Modbus API

Pascal로 작성되어 애플리케이션에 컴파일되는 비시각 컴포넌트 형태의 Modbus TCP 및 Modbus RTU 마스터와 슬레이브.

Delphi Modbus 라이브러리를 사용하면 VCL, FMX, 서비스, 콘솔 애플리케이션이 모든 공장 현장에 있는 장치, 즉 PLC, 주파수 드라이브, 전력량계, 온도 컨트롤러, 프로토콜 게이트웨이와 통신할 수 있어요. sgcWebSockets는 이를 네 개의 컴포넌트로 제공해요. TsgcModbusTCPClient와 TsgcModbusRTUClient는 장치를 폴링하고, TsgcModbusTCPServer와 TsgcModbusRTUServer는 내 데이터를 SCADA 시스템, HMI, 그 밖의 Modbus 마스터에 제공해요.

두 클라이언트는 모두 TsgcModbusClient_Base에서 파생되므로, 이더넷으로 레지스터를 읽는 코드는 RS-485로도 그대로 읽어요. 호출은 그대로 두고 컴포넌트만 바꾸면 돼요. 각 호출은 응답이 도착하거나 Timeout이 만료될 때까지 블로킹되며, 값을 Delphi 배열로 반환하고, 장치가 오류를 보고하면 타입 예외를 발생시켜요. uses sgcIndustrial; 한 줄이면 모든 클래스가 포함돼요.

컴포넌트 클래스

TsgcModbusTCPClient, TsgcModbusRTUClient, TsgcModbusTCPServer, TsgcModbusRTUServer, TsgcModbusDataModel

전송

포트 502의 Modbus TCP(선택적 TLS와 프록시), TsgcSerialPort를 통한 RS-232 및 RS-485 Modbus RTU

기능 코드

01~08, 15, 16, 22, 23, 43/14(장치 식별 읽기)

플랫폼

Delphi 7~Delphi 13 및 C++Builder, Windows, Linux, macOS

일반적인 Modbus 기능마다 메서드 하나씩

클라이언트는 아무것도 전송하기 전에 수량을 사양에 맞게 검사하며, 서버는 이 표의 모든 코드에 응답해요.

FC기능클라이언트 메서드
01Read CoilsReadCoils
02Read Discrete InputsReadDiscreteInputs
03Read Holding RegistersReadHoldingRegisters, ReadInt32, ReadUInt32, ReadFloat32, ReadString
04Read Input RegistersReadInputRegisters, ReadInputInt32, ReadInputUInt32, ReadInputFloat32
05Write Single CoilWriteSingleCoil
06Write Single RegisterWriteSingleRegister
07Read Exception Status (시리얼 회선)RTU 클라이언트의 ReadExceptionStatus
08Diagnostics (시리얼 회선)RTU 클라이언트의 Diagnostics
15Write Multiple CoilsWriteMultipleCoils
16Write Multiple RegistersWriteMultipleRegisters, WriteInt32, WriteUInt32, WriteFloat32, WriteString
22Mask Write RegisterMaskWriteRegister
23Read/Write Multiple RegistersReadWriteMultipleRegisters
43/14Read Device IdentificationReadDeviceIdentification (basic, regular, extended, 단일 객체)

몇 줄의 Delphi로 PLC 읽기

컴포넌트를 만들고, 주소를 설정하고, 메서드를 호출해요. 이 페이지의 모든 샘플은 Delphi 7과 Delphi 13에서 컴파일돼요.

uses
  sgcIndustrial;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Modbus := TsgcModbusTCPClient.Create(Self);
  Modbus.Host := '192.168.1.50';
  Modbus.Port := 502;
  Modbus.UnitId := 1;
  Modbus.Timeout := 2000;          // ms per attempt
  Modbus.Retries := 2;             // extra attempts after a timeout
  Modbus.WatchDog.Enabled := True; // reconnect after a network drop
  Modbus.OnConnect := ModbusConnect;
  Modbus.OnError := ModbusError;
  Modbus.Active := True;
end;

procedure TForm1.ModbusConnect(Sender: TObject);
begin
  Memo1.Lines.Add('connected');
end;

procedure TForm1.ModbusError(Sender: TObject; const aError: string);
begin
  Memo1.Lines.Add('error: ' + aError);
end;

procedure TForm1.btnReadClick(Sender: TObject);
var
  vRegisters: TsgcModbusRegisters;
  vCoils: TsgcModbusBits;
  i: Integer;
begin
  vRegisters := Modbus.ReadHoldingRegisters(0, 10); // FC 03
  for i := 0 to Length(vRegisters) - 1 do
    Memo1.Lines.Add(Format('HR%d = %d', [i, vRegisters[i]]));

  vCoils := Modbus.ReadCoils(0, 8);                 // FC 01
  if vCoils[0] then
    Memo1.Lines.Add('coil 0 is on');

  Modbus.WriteSingleRegister(100, 1234);            // FC 06
  Modbus.WriteSingleCoil(5, True);                  // FC 05
end;
procedure TForm1.btnTypedClick(Sender: TObject);
var
  vTemperature: Single;
  vCounter: Integer;
  vName: TsgcModbusAnsiString;
begin
  Modbus.WordOrder := mwoCDAB;              // low word first
  vTemperature := Modbus.ReadFloat32(200);  // 2 holding registers
  vCounter := Modbus.ReadInt32(202);
  vName := Modbus.ReadString(300, 8);       // 8 registers, 16 characters
  Memo1.Lines.Add(Format('%s: %.1f C, %d cycles',
    [string(vName), vTemperature, vCounter]));

  Modbus.WriteFloat32(210, 21.5);
  Modbus.WriteUInt32(212, 3000000000);

  // explicit unit id, for a gateway with several devices behind it
  Memo1.Lines.Add(FloatToStr(Modbus.ReadInputFloat32(7, 0))); // unit 7, FC 04

  try
    Modbus.ReadHoldingRegisters(9000, 4);
  except
    on E: EsgcModbusException do // the device answered with an exception
      Memo1.Lines.Add(Format('exception %d, function %d',
        [E.ExceptionCode, E.FunctionCode]));
    on E: EsgcModbusTimeout do   // no answer after Retries + 1 attempts
      Memo1.Lines.Add(E.Message);
  end;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
  Serial := TsgcSerialPort.Create(Self);
  Serial.Port := 'COM3';          // '/dev/ttyUSB0' on Linux
  Serial.BaudRate := 19200;
  Serial.Parity := spEven;        // 8E1, the Modbus RTU default
  Serial.RtsControl := srcToggle; // RS-485: RTS switches the transmitter
  Serial.Active := True;

  RTU := TsgcModbusRTUClient.Create(Self);
  RTU.SerialPort := Serial;
  RTU.UnitId := 17;               // slave address
  RTU.Timeout := 500;
  RTU.Retries := 1;
end;

procedure TForm1.btnPollClick(Sender: TObject);
var
  vValues: TsgcModbusRegisters;
begin
  vValues := RTU.ReadInputRegisters(0, 4);                      // FC 04
  Memo1.Lines.Add(Format('IR0 = %d', [vValues[0]]));
  Memo1.Lines.Add(Format('status = %d', [RTU.ReadExceptionStatus])); // FC 07
  RTU.WriteSingleRegister(0, 10, 500); // unit 0: broadcast to every slave, no reply
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
  Server := TsgcModbusTCPServer.Create(Self);
  Server.Port := 502;
  Server.UnitId := 0;                          // answer every unit id
  Server.DataModel.HoldingRegisterCount := 1000;
  Server.DataModel.SetHoldingRegister(0, 42);
  Server.DataModel.SetCoil(0, True);
  Server.DataModel.VendorName := 'My Company'; // FC 43/14 identification
  Server.DataModel.ProductCode := 'GW-100';
  Server.OnReadRequest := ServerReadRequest;
  Server.OnWriteRequest := ServerWriteRequest;
  Server.Active := True;
end;

// runs in the connection thread, before the table is read
procedure TForm1.ServerReadRequest(Sender: TObject; aUnitId, aFunctionCode: Byte;
  aAddress, aCount: Word; var aExceptionCode: Byte);
begin
  if aFunctionCode = CS_MODBUS_FC_READ_INPUT_REGISTERS then
    Server.DataModel.SetInputRegister(0, Random(1000)); // fresh value
end;

// registers 0..9 are read only
procedure TForm1.ServerWriteRequest(Sender: TObject; aUnitId, aFunctionCode: Byte;
  aAddress, aCount: Word; var aBits: TsgcModbusBits;
  var aRegisters: TsgcModbusRegisters; var aExceptionCode: Byte);
begin
  if (Length(aRegisters) > 0) and (aAddress < 10) then
    aExceptionCode := CS_MODBUS_EX_ILLEGAL_DATA_ADDRESS;
end;

어떤 스레드에서도 호출할 수 있는 Modbus 마스터

TCP와 시리얼 회선에서 블로킹 호출, 타입 값, 명확한 오류를 제공해요.

타입 32비트 값과 문자열

ReadFloat32, ReadInt32, ReadUInt32와 대응하는 쓰기 및 입력 레지스터 메서드는 두 레지스터를 하나의 값으로 결합해요. WordOrder는 장치가 사용하는 네 가지 배치를 지원해요. mwoABCD(빅 엔디안, Modbus 기본값), mwoCDAB, mwoBADC, mwoDCBA. ReadString과 WriteString은 레지스터당 두 문자를 담아요.

스레드 안전 블로킹 호출

클라이언트당 한 번에 하나의 요청만 실행되며, 모든 재시도를 포함하는 잠금으로 보호되므로 여러 스레드가 하나의 연결을 공유할 수 있어요. TCP에서는 수신 스레드가 응답을 대응시키므로 메인 스레드에서 호출해도 교착 상태가 생기지 않아요.

타임아웃과 재시도

Timeout은 시도당 대기 시간이고 Retries는 추가 시도 횟수예요. TCP 재시도는 새 트랜잭션 ID를 사용하며, 늦게 도착했거나 중복된 응답은 다음 응답으로 오인되지 않고 버려져요.

타입 예외

EsgcModbusException은 장치의 ExceptionCode와 FunctionCode를 담고, EsgcModbusTimeout은 응답이 없음을 알리며, EsgcModbusError는 닫힌 연결부터 CRC가 잘못된 RTU 프레임까지 그 밖의 모든 경우를 다뤄요.

호출별 유닛 ID

모든 메서드에는 앞에 유닛 ID를 받는 오버로드도 있어, 게이트웨이에 대한 하나의 연결로 그 뒤의 모든 장치에 접근할 수 있어요. 유닛 ID가 없는 호출에는 UnitId가 기본값으로 쓰여요.

TCP의 TLS, 프록시, 재연결

TLS와 TLSOptions는 Modbus TCP 스트림을 TLS로 감싸고, Proxy는 HTTP 또는 SOCKS 프록시를 통해 장치에 도달하며, WatchDog는 네트워크가 끊긴 뒤 재연결해요. 세 가지 모두 컴포넌트의 기반인 sgcWebSockets TCP 클라이언트에서 제공돼요.

제대로 구현한 RTU 프레이밍

RTU 클라이언트는 전송 전에 3.5 문자 시간의 무음을 기다리고, 예상 길이로 응답을 읽으며(USB 어댑터는 바이트를 묶음으로 전달해요), 모든 프레임의 CRC를 검사하고, 다른 슬레이브 주소의 프레임은 무시해요.

RS-485와 브로드캐스트

시리얼 포트에 RtsControl := srcToggle을 설정하면, Windows에서는 드라이버를 통해, Linux에서는 커널 RS-485 모드를 통해 쓸 때마다 RTS가 RS-485 송신기를 전환해요. 유닛 ID 0은 모든 슬레이브에 브로드캐스트 쓰기를 보내며, 응답 대신 TurnaroundDelay만큼 기다려요.

원하는 곳에서 이벤트 받기

OnConnect, OnDisconnect, OnError는 NotifyEvents에 따라 전달돼요. 기본값은 메인 스레드에 큐잉하는 것이며, 동기화하거나 수신 스레드에서 직접 발생시킬 수도 있어요.

실시간 데이터 모델을 갖춘 Modbus TCP 및 RTU 서버

Delphi 애플리케이션을 Modbus 슬레이브로 만드세요. 데이터베이스나 REST API의 값을 노출하는 게이트웨이, HMI 화면을 테스트하는 장치 시뮬레이터, 또는 내 컨트롤러의 Modbus 인터페이스가 될 수 있어요. 각 서버는 네 개의 Modbus 테이블(코일, 이산 입력, 홀딩 레지스터, 입력 레지스터, 각각 기본 10,000개, 최대 65,536개), FC 43/14에 응답하는 장치 식별 문자열, FC 07에 응답하는 예외 상태를 갖는 TsgcModbusDataModel을 소유해요.

데이터 모델은 스레드 안전해요. 하나의 잠금이 모든 테이블을 보호하므로, 클라이언트가 읽는 동안에도 코드가 값을 갱신할 수 있어요. 두 개의 훅이 요청 경로에 코드를 끼워 넣어요. OnReadRequest는 테이블을 읽기 전에 실행되어 값을 적시에 갱신하거나 예외 코드로 요청을 거부할 수 있어요. OnWriteRequest는 값이 저장되기 전에 받아서 검증하거나, 바꾸거나, 쓰기를 거부하고 테이블을 그대로 둘 수 있어요.

TsgcModbusTCPServer

각자 자기 스레드를 가진 다수의 동시 연결을 지원해요. 한 패킷에 함께 도착한 요청은 순서대로 응답하고, 여러 패킷에 나뉜 요청은 다시 조립하며, 잘못된 헤더는 해당 연결을 닫고 OnError를 발생시켜요. UnitId = 0은 모든 유닛 ID에 응답하고, 다른 값은 해당 ID에만 응답해요. Bindings로 인터페이스와 포트를 선택하며, OnClientConnect와 OnClientDisconnect가 피어를 알려 줘요.

TsgcModbusRTUServer

TsgcSerialPort에서 슬레이브 UnitId(1~247)로 수신해요. 요청을 예상 길이와 3.5 문자 시간의 무음으로 프레이밍하고, CRC가 잘못되었거나 다른 주소의 프레임은 무시하며, 시리얼 회선 사양에 따라 유닛 ID 0의 브로드캐스트 쓰기는 응답 없이 실행해요.

연결 스레드의 훅

서버 이벤트는 연결 스레드(TCP) 또는 프레임 스레드(RTU)에서 실행되며 결과를 동기적으로 반환해요. 짧게 유지하고, 데이터 모델 메서드는 자유롭게 호출하세요. 훅은 잠금을 잡지 않은 상태로 실행돼요.

독립적인 Modbus 스택으로 테스트

Modbus 클라이언트와 서버는 독립적인 오픈 소스 구현인 pymodbus를 대상으로 Modbus TCP 통신선에서 테스트됐어요. 기능 코드 01~06, 15, 16, 22, 23, 43/14, 예외 응답, Float32 값, 장치 식별이 포함돼요. 타입 헬퍼는 네 가지 워드 순서 모두에서 알려진 바이트 벡터로 검증돼요. Delphi 컴포넌트는 sgcWebSockets .NET Modbus 컴포넌트와도 클라이언트 대 서버로 양방향 테스트되었으며, 각 방향에서 35개 검사 중 35개가 통과했어요.

시리얼 포트는 Windows의 실제 COM 포트와 Linux의 의사 터미널에서 테스트되었으며, 읽기 대기 중에 포트를 닫는 경우도 포함돼요. Modbus RTU 클라이언트와 서버는 시뮬레이션된 슬레이브와 마스터를 대상으로 테스트됐어요. 분할된 프레임, CRC 오류, 다른 슬레이브 주소, 브로드캐스트가 해당돼요. 같은 코드가 macOS에서도 컴파일돼요.

Delphi Modbus 관련 질문

TsgcModbusTCPClient를 만들고 Host, Port(기본값 502), UnitId를 설정한 다음 Active := True로 지정하고 ReadHoldingRegisters(Address, Count)를 호출하세요. 레지스터당 Word 하나를 담은 TsgcModbusRegisters 배열을 반환해요. 주소는 통신선에서 전송되는 대로 0부터 시작해요.

두 레지스터 중 첫 번째 주소로 ReadFloat32, ReadInt32, ReadUInt32를 호출하세요. 입력 레지스터는 ReadInput... 변형을 사용해요. 값이 이상하면 장치가 다른 워드 순서를 사용하는 것이므로, WordOrder를 기본값 mwoABCD 대신 mwoCDAB, mwoBADC, mwoDCBA로 설정하세요.

네. 어댑터에 TsgcSerialPort를 열고 TsgcModbusRTUClient 또는 TsgcModbusRTUServer의 SerialPort 속성에 지정하세요. 방향을 자동으로 제어하는 어댑터는 다른 설정이 필요 없어요. RTS로 송신기를 전환하는 어댑터에는 RtsControl := srcToggle을 설정하세요. Windows는 드라이버의 RTS 토글 모드를, Linux는 커널 RS-485 모드를 사용해요.

네. 클라이언트는 한 번에 하나의 트랜잭션을 실행하고 재시도를 포함한 요청 전체 동안 잠금을 유지하므로, 여러 스레드의 호출이 큐에 쌓이고 각각 자신의 응답을 받아요. 메인 스레드에서 호출해도 교착 상태가 생기지 않아요. TCP에서는 응답을 별도 스레드가 수신하기 때문이에요.

TsgcModbusTCPServer(또는 시리얼 포트를 쓰는 TsgcModbusRTUServer)를 올리고, SetHoldingRegister, SetCoil 등의 setter로 DataModel을 채운 다음 Active := True로 설정하세요. OnReadRequest와 OnWriteRequest를 사용하면 값을 필요할 때 계산하거나 Modbus 예외 코드로 쓰기를 거부할 수 있어요.

Delphi 7~Delphi 13 및 C++Builder, Windows(32/64비트), Linux 64비트, macOS. 시리얼 포트와 그에 따라 Modbus RTU는 Android와 iOS에서 사용할 수 없어요.

Modbus 및 시리얼 포트 컴포넌트는 sgcWebSockets Enterprise(Delphi 및 .NET)와 All-Access, 또는 독립형 sgcIndustrial 팩에 포함돼요.

sgcWebSockets의 더 많은 산업용 컴포넌트

산업용 컴포넌트

시리얼 포트, Modbus, OPC UA 클라이언트를 하나의 섹션에서, 전체 컴포넌트 레퍼런스와 함께 제공해요.

Modbus 클라이언트 레퍼런스

TsgcModbusTCPClient와 TsgcModbusRTUClient의 속성, 메서드, 이벤트.

Modbus 서버 레퍼런스

TsgcModbusTCPServer, TsgcModbusRTUServer, TsgcModbusDataModel 훅.

Delphi 시리얼 포트

Windows, Linux, macOS용 TsgcSerialPort: Modbus RTU의 전송 계층이자 독립적인 시리얼 컴포넌트.

Delphi MQTT 클라이언트

Modbus 값을 MQTT 브로커에 게시하세요. 공장 데이터를 클라우드로 보내는 일반적인 방법이에요.

C#과 .NET에서도 사용 가능

같은 클래스 이름을 쓰는 동일한 Modbus 클라이언트와 서버를 .NET 8, 9, 10 및 .NET Standard 2.0용으로 제공해요.

최고의 가성비: All-Access모든 eSeGeCe 제품과 프리미엄 지원이 포함되어 연 €1,059부터 이용할 수 있어요.
All-Access 가격 보기

Delphi에서 첫 PLC와 통신하기

sgcWebSockets Enterprise(Delphi 및 .NET)와 All-Access, 또는 독립형 sgcIndustrial 팩에 포함.