Form Builder

uses
  sgcHTML_Component_Form, sgcHTML_Component_FormBuilder;

// 폼에 TsgcHTMLComponent_Form (Form1)과
// TsgcHTMLComponent_FormBuilder (FormBuilder1)를 두고 Form = Form1로 설정합니다

procedure TMainModule.FormBuilder1Save(Sender: TObject; const aJSON: string;
  var aAccept: Boolean; var aErrorMessage: string);
begin
  // aJSON은 정규화된 정의이며 서버에서 이미 검사했습니다
  StoreDefinition('contact', aJSON);   // 자체 저장소: 파일, 테이블 등
end;

// 공개 페이지: 요청마다 폼 하나를 저장된 디자인에서 로드합니다
function TMainModule.ContactPage: string;
var
  oForm: TsgcHTMLComponent_Form;
begin
  oForm := TsgcHTMLComponent_Form.Create(nil);
  try
    oForm.Action := '/f/contact';
    oForm.LoadFromJSON(ReadDefinition('contact'));
    Result := oForm.HTML;
  finally
    oForm.Free;
  end;
end;

// 제출 시: 유효성을 검사한 다음 형식이 지정된 값을 보관합니다
function TMainModule.ContactPost(const aParams: TStrings): string;
var
  oForm: TsgcHTMLComponent_Form;
  oErrors: TStringList;
begin
  oForm := TsgcHTMLComponent_Form.Create(nil);
  oErrors := TStringList.Create;
  try
    oForm.LoadFromJSON(ReadDefinition('contact'));
    if oForm.Validate(aParams, oErrors) then
    begin
      StoreResponse('contact', oForm.GetValuesJSON(aParams));
      Result := ThankYouPage;
    end
    else
      Result := oForm.GetValidationResponse(oErrors);
  finally
    oErrors.Free;
    oForm.Free;
  end;
end;