Form Builder

uses
  sgcHTML_Component_Form, sgcHTML_Component_FormBuilder;

// Na formularzu: TsgcHTMLComponent_Form (Form1) i
// TsgcHTMLComponent_FormBuilder (FormBuilder1) z Form = Form1

procedure TMainModule.FormBuilder1Save(Sender: TObject; const aJSON: string;
  var aAccept: Boolean; var aErrorMessage: string);
begin
  // aJSON to znormalizowana definicja, już sprawdzona przez serwer
  StoreDefinition('contact', aJSON);   // własny magazyn: plik, tabela
end;

// Strona publiczna: formularz na żądanie, wczytany z zapisanego projektu
function TMainModule.ContactPage: string;
var
  oForm: TsgcHTMLComponent_Form;
begin
  oForm := TsgcHTMLComponent_Form.Create(nil);
  try
    oForm.Action := '/f/contact';
    oForm.LoadFromJSON(ReadDefinition('contact'));
    Result := oForm.HTML;
  finally
    oForm.Free;
  end;
end;

// Przy wysyłce: zwalidować, a następnie zachować otypowane wartości
function TMainModule.ContactPost(const aParams: TStrings): string;
var
  oForm: TsgcHTMLComponent_Form;
  oErrors: TStringList;
begin
  oForm := TsgcHTMLComponent_Form.Create(nil);
  oErrors := TStringList.Create;
  try
    oForm.LoadFromJSON(ReadDefinition('contact'));
    if oForm.Validate(aParams, oErrors) then
    begin
      StoreResponse('contact', oForm.GetValuesJSON(aParams));
      Result := ThankYouPage;
    end
    else
      Result := oForm.GetValidationResponse(oErrors);
  finally
    oErrors.Free;
    oForm.Free;
  end;
end;