新增

Delphi OPC UA 客户端组件

适用于 Delphi 和 C++Builder 的原生 OPC UA 客户端。浏览、读取和写入 PLC、SCADA 服务器和工业网关的变量,调用它们的方法,并通过订阅接收数据变化和报警,连接基于经过签名和加密的 opc.tcp,并能自动重连。

包含在 sgcWebSockets Enterprise(Delphi 和 .NET)和 All-Access 或独立的 sgcIndustrial 软件包中。

一个组件,覆盖 OPC UA 的客户端

安全通道、会话、服务和订阅集成在一个非可视组件中,用 Pascal 编写并编译进您的应用程序。

Delphi OPC UA 客户端让 VCL、FMX、服务或控制台应用程序能够读取机器、PLC 和 SCADA 系统通过 OPC UA 服务器发布的数据,并把设定值和命令写回去。sgcWebSockets 以 TsgcOPCUAClient 提供:设置 EndpointUrl,选择 SecurityPolicy 和 SecurityMode,调用 Connect,然后使用 ns=2;s=Line1.Speed 或 i=2253 这样的节点 ID 进行操作。

服务调用会阻塞直到服务器应答,失败时抛出带有 OPC UA 状态码的 EsgcOPCUAError。ReadValue 返回 Delphi Variant,WriteValue 会先读取节点的数据类型,因此 WriteValue('ns=2;s=Line1.Setpoint', 75.5) 会按节点要求写入 Float 或 Double。只需一行 uses sgcIndustrial; 就能引入组件、它的类型和枚举。

组件类

TsgcOPCUAClient,以及 TsgcOPCUASubscription 和 TsgcOPCUAMonitoredItem

传输

基于 opc.tcp 的 OPC UA 二进制,PLC 和 SCADA 服务器提供的传输方式

安全

使用 Basic256Sha256、Aes128_Sha256_RsaOaep 和 Aes256_Sha256_RsaPss 的 Sign 和 SignAndEncrypt

平台

Delphi 7 到 Delphi 13 和 C++Builder;Windows 32 位和 64 位以及 Linux 64 位

OPC UA 服务,每个服务对应一个方法

简单重载接受节点 ID 字符串;完整重载接受规范中的请求记录。

服务集服务方法
发现GetEndpointsGetEndpoints
视图Browse, BrowseNextBrowse, BrowseNext
视图TranslateBrowsePathsToNodeIdsTranslateBrowsePath
属性ReadRead, ReadValue
属性WriteWrite, WriteValue
方法CallCall
订阅CreateSubscription, DeleteSubscriptions, SetPublishingModeCreateSubscription, DeleteSubscription, SetPublishingMode
MonitoredItemCreateMonitoredItems, ModifyMonitoredItems, DeleteMonitoredItemsAddMonitoredItem, AddEventMonitoredItem, ModifyMonitoredItem, RemoveMonitoredItem
订阅Publish, Republish, TransferSubscriptions由组件完成:OnDataChange、OnEvent、OnKeepAlive、WatchDog

用几行 Delphi 代码读取一台机器

创建组件,设置端点,调用方法。本页的每个示例都可以在 Delphi 7 和 Delphi 13 中编译。

uses
  sgcIndustrial;

procedure TForm1.ReadLine1;
begin
  OPCUA := TsgcOPCUAClient.Create(Self);
  OPCUA.EndpointUrl := 'opc.tcp://192.168.1.60:4840';
  OPCUA.Connect;
  try
    Memo1.Lines.Add('Speed: ' + VarToStr(OPCUA.ReadValue('ns=2;s=Line1.Speed')));
    // write with an explicit built-in type
    OPCUA.WriteValue('ns=2;s=Line1.Mode', 2, uabtUInt16);
  except
    on E: EsgcOPCUAError do
      Memo1.Lines.Add('Status ' + IntToHex(Int64(E.StatusCode), 8) + ': ' + E.Message);
  end;
end;
uses
  sgcIndustrial, sgcOPCUA_Types;

procedure TForm1.BrowseAndCall;
var
  vRefs: TsgcOPCUAReferenceDescriptionArray;
  vInputs, vOutputs: TsgcOPCUAVariantArray;
  i: Integer;
begin
  // i=85 is the Objects folder
  vRefs := OPCUA.Browse('i=85');
  for i := 0 to Length(vRefs) - 1 do
    Memo1.Lines.Add(vRefs[i].DisplayName.Text + ' = ' +
      sgcOPCUANodeIdToString(vRefs[i].NodeId.NodeId));
  // resolve a browse path to a node id
  Memo1.Lines.Add(sgcOPCUANodeIdToString(OPCUA.TranslateBrowsePath('i=85', '/2:Line1/2:Speed')));
  // call a method with two Int32 arguments
  SetLength(vInputs, 2);
  vInputs[0] := sgcOPCUAVariantSimple(uabtInt32, 2);
  vInputs[1] := sgcOPCUAVariantSimple(uabtInt32, 3);
  vOutputs := OPCUA.Call('ns=2;s=Methods', 'ns=2;s=Methods.Add', vInputs);
  Memo1.Lines.Add('Result: ' + VarToStr(vOutputs[0].Value));
end;
procedure TForm1.WatchLine1;
var
  oSubscription: TsgcOPCUASubscription;
begin
  OPCUA.OnDataChange := OnOPCUADataChange;
  oSubscription := OPCUA.CreateSubscription(1000);
  // sampling 100 ms, keep the 10 newest samples between two publishes
  FSpeed := OPCUA.AddMonitoredItem(oSubscription, 'ns=2;s=Line1.Speed', 100, 10);
  // only changes of more than 2 percent of the EURange of the variable
  OPCUA.AddMonitoredItem(oSubscription, 'ns=2;s=Line1.Level', 500, 1, True, uadbtPercent, 2);
end;

procedure TForm1.OnOPCUADataChange(Sender: TObject; aSubscription: TsgcOPCUASubscription;
  aMonitoredItem: TsgcOPCUAMonitoredItem; const aValue: TsgcOPCUADataValue);
begin
  if aMonitoredItem = FSpeed then
    Memo1.Lines.Add('Speed: ' + VarToStr(aValue.Value.Value))
  else
    Memo1.Lines.Add('Level: ' + VarToStr(aValue.Value.Value));
end;
uses
  sgcIndustrial, sgcOPCUA_Encoding;

procedure TForm1.WatchAlarms;
var
  oSubscription: TsgcOPCUASubscription;
begin
  OPCUA.OnEvent := OnOPCUAEvent;
  oSubscription := OPCUA.CreateSubscription(1000);
  // i=2253 is the Server object, which reports the events of the whole server
  OPCUA.AddEventMonitoredItem(oSubscription, 'i=2253', ['Message', 'Severity', 'SourceName']);
end;

procedure TForm1.OnOPCUAEvent(Sender: TObject; aSubscription: TsgcOPCUASubscription;
  aMonitoredItem: TsgcOPCUAMonitoredItem; const aEventFields: TsgcOPCUAVariantArray);
begin
  // the fields arrive in the order of the select clauses
  Memo1.Lines.Add(VarToStr(sgcOPCUAVariantToDelphi(aEventFields[2])) + ' (' +
    VarToStr(sgcOPCUAVariantToDelphi(aEventFields[1])) + '): ' +
    VarToStr(sgcOPCUAVariantToDelphi(aEventFields[0])));
end;
procedure TForm1.StartMonitor;
begin
  OPCUA := TsgcOPCUAClient.Create(Self);
  OPCUA.EndpointUrl := 'opc.tcp://192.168.1.60:4840';
  // try to reconnect every 5 seconds, with no limit of attempts
  OPCUA.WatchDog.Enabled := True;
  OPCUA.WatchDog.Interval := 5;
  OPCUA.WatchDog.Attempts := 0;
  OPCUA.OnStatusChange := OnOPCUAStatusChange;
  OPCUA.OnReconnect := OnOPCUAReconnect;
  OPCUA.Connect;
end;

procedure TForm1.OnOPCUAStatusChange(Sender: TObject; aState: TsgcOPCUAClientState);
begin
  if aState = opccsReconnecting then
    Memo1.Lines.Add('Connection lost, reconnecting');
end;

procedure TForm1.OnOPCUAReconnect(Sender: TObject; aMethod: TsgcOPCUAReconnectMethod);
begin
  case aMethod of
    opcrmSessionReactivated:
      Memo1.Lines.Add('Same session, missing notifications republished');
    opcrmSubscriptionsTransferred:
      Memo1.Lines.Add('New session, subscriptions transferred');
    opcrmSubscriptionsRecreated:
      Memo1.Lines.Add('New session, subscriptions created again');
  else
    Memo1.Lines.Add('New session');
  end;
end;

辅助函数 sgcOPCUANodeIdToString 和 sgcOPCUAVariantSimple 位于 sgcOPCUA_Types,sgcOPCUAVariantToDelphi 位于 sgcOPCUA_Encoding;使用它们时请添加这些单元。Delphi 7 到 2006 还需要 sgcBase_Helpers 来支持 TBytes。

为工厂车间打造的 OPC UA 客户端

订阅、过滤器和重连都替您处理好,需要的地方提供事件。

无需轮询的订阅

CreateSubscription 设置发布间隔,AddMonitoredItem 设置每个节点的采样间隔和队列大小。组件会保持足够的 Publish 请求在途,确认每条通知,并请求服务器重新发布任何丢失的消息。

死区和触发器

绝对死区(uadbtAbsolute)或 EURange 的百分比(uadbtPercent)可以让噪声不进入您的处理程序。触发器决定报告的是状态变化、数值变化还是新的时间戳。

事件和报警

AddEventMonitoredItem 接受要返回的事件字段,例如 Message、Severity 和 SourceName,以及可选的 where 子句。可以订阅单个来源,也可以订阅 Server 对象以获取服务器的所有事件。

WatchDog 重连

网络中断后,WatchDog 首先重新激活同一个会话,并重新发布错过的通知。如果会话已不存在,则打开新会话并转移订阅,或重新创建订阅。OnReconnect 会报告走的是哪条路径。

重连后对象保持不变

订阅和监控项由客户端持有,在 WatchDog 重连后依然存在。服务器端 ID 可能改变,但监控项的 ClientHandle 永远不变,因此您的处理程序可以继续工作。

按需处理事件

OnDataChange、OnEvent、OnKeepAlive、OnConnect、OnDisconnect 和 OnError 通过 NotifyEvents 传递:默认排队到主线程,也可以同步触发,或者在客户端线程中触发,适用于服务和控制台应用程序。

签名并加密,默认值安全

把 SecurityPolicy 设置为 opcspBasic256Sha256、opcspAes128_Sha256_RsaOaep 或 opcspAes256_Sha256_RsaPss,把 SecurityMode 设置为 opcsmSign 或 opcsmSignAndEncrypt。opcspBasic128Rsa15 和 opcspBasic256 已被 OPC 基金会弃用,仅用于较旧的服务器。客户端从 GetEndpoints 中选取匹配的端点,如果没有匹配项,错误信息会列出服务器提供的选项。

应用程序证书

Application.CertificateFile 和 PrivateKeyFile 加载实例证书。如果这些文件尚不存在,客户端会创建证书并保存到那里,服务器管理员只需信任一次。未设置文件时,证书在内存中创建。

服务器证书

除非 OnValidateServerCertificate 接受,否则服务器证书会被拒绝,因此全新的客户端不会意外信任未知的服务器。AutoAcceptServerCertificate 仅用于测试环境。

用户身份

Authentication.AuthenticationType 可选择匿名、用户名和密码,或 X.509 用户证书。只要服务器的令牌策略要求,密码就会用服务器密钥加密。

已对照独立的 OPC UA 栈测试

客户端已在线路层面对照基于 asyncua 构建的参考服务器进行测试,asyncua 是一个独立的开源 OPC UA 实现:服务器的全部十一个端点(每种策略和模式)、三种身份类型、带延续点浏览 1,000 个引用、读取 18 种内置类型(含数组和矩阵)、写入标量和数组、方法调用、带死区和 where 子句的数据变化和事件订阅、两分钟的发布运行且无丢失或重复的消息,以及 WatchDog 的每条重连路径。

Delphi OPC UA 常见问题

创建 TsgcOPCUAClient,把 EndpointUrl 设置为服务器的 opc.tcp 地址,调用 Connect,然后调用 ReadValue('ns=2;s=Line1.Speed')。它返回 Variant。Read 可以一次调用读取多个节点和属性。

用发布间隔调用 CreateSubscription,用 AddMonitoredItem 添加节点,并为 OnDataChange 赋值。事件会收到订阅、监控项以及带有状态码和时间戳的新 TsgcOPCUADataValue。

Sign 或 SignAndEncrypt 模式下的 Basic256Sha256、Aes128_Sha256_RsaOaep 和 Aes256_Sha256_RsaPss,另有用于较旧服务器的已弃用的 Basic128Rsa15 和 Basic256,以及用于测试环境的 None。

启用 WatchDog.Enabled 后,客户端每隔 WatchDog.Interval 秒重试一次。如果服务器仍保留会话,它会重新激活同一个会话,否则会打开新会话并转移或重新创建订阅。OnReconnect 会报告走的是哪条路径,您的订阅对象保持有效。

可以。没有消息循环时请设置 NotifyEvents := neNoSync:事件将在客户端线程中运行。不要在这些事件中调用 Connect 或其他阻塞服务,请让 WatchDog 负责重连。

Delphi 7 到 Delphi 13 和 C++Builder,支持 Windows(32 位和 64 位)和 Linux 64 位。

OPC UA 客户端包含在 sgcWebSockets Enterprise(Delphi 和 .NET)和 All-Access 或独立的 sgcIndustrial 软件包中。它不包含 OPC UA 服务器、HTTPS、JSON 和 WebSocket 传输、HistoryRead、PubSub、Reverse Connect 和 Global Discovery Server。

sgcWebSockets 中更多的工业组件

工业组件

串口、Modbus 和 OPC UA 集中在同一个栏目中,附完整的组件参考。

OPC UA 客户端参考

TsgcOPCUAClient 的属性、方法和事件,附 C++Builder 和 C# 示例。

Delphi Modbus TCP 和 RTU

适用于不支持 OPC UA 的设备的 Modbus 客户端和服务器。

Delphi MQTT 客户端

把 OPC UA 数据变化转发到 MQTT 主题:从工厂到云端的常用网关。

也适用于 C# 和 .NET

相同的 OPC UA 客户端,类名也相同,适用于 .NET 8、9、10 和 .NET Standard 2.0。

超值之选:All-AccesseSeGeCe 全部产品,含高级支持,每年 €1,059 起。
查看 All-Access 价格

从 Delphi 读取您的第一个 OPC UA 节点

包含在 sgcWebSockets Enterprise(Delphi 和 .NET)和 All-Access 或独立的 sgcIndustrial 软件包中。