WebSockets TMS Sparkle

Ein Kunde fragte, ob TMS Sparkle und sgcWebSockets zusammen laufen können, und die Antwort lautet ja: es gibt keine Probleme, sgcWebSockets und TMS Sparkle auf demselben Server zu betreiben. Beide können auf einem HTTP.SYS-Server laufen, du kannst einen einzigen HTTP.SYS-Server betreiben und Endpunkte für Sparkle und sgcWebSockets problemlos konfigurieren. Im Wesentlichen konfigurierst du in jedem Paket, welcher Endpunkt verarbeitet wird.

sgcWebSockets kann über den HTTP API Server in HTTP.SYS-Server ausgeführt werden:

https://www.esegece.com/help/sgcWebSockets/#t=Components%2FTsgcWebSocketServer_HTTPAPI.htm

Unten findest du 2 Beispiele, die zeigen, wie sgcWebSockets und TMS Sparkle auf demselben HTTP.SYS-Server laufen können.

sgcWebSockets-Beispiel

program sgcWSServer;
{$APPTYPE CONSOLE}
{$R *.res}
uses
  System.SysUtils,
  sgcWebSocket, sgcWebSocket_Classes,
  sgcWebSocket_Server_HTTPAPI;
type
  TsgcServerClass = class
    public
      procedure OnConnectEvent(Connection: TsgcWSConnection);
      procedure OnMessageEvent(Connection: TsgcWSConnection; const Text: String);
  end;
procedure TsgcServerClass.OnConnectEvent(Connection: TsgcWSConnection);
begin
   Connection.WriteData('Hello From Server.');
end;
procedure TsgcServerClass.OnMessageEvent(Connection: TsgcWSConnection; const
    Text: String);
begin
  Connection.WriteData(Text);
end;
var
  oServer: TsgcWebSocketServer_HTTPAPI;
  oConnection: TsgcServerClass;
begin
  try
    oServer := TsgcWebSocketServer_HTTPAPI.Create(nil);
    oConnection := TsgcServerClass.Create;
    Try
      oServer.Bindings.NewBinding('127.0.0.1', 2001, '/ws/');
      oServer.OnConnect := oConnection.OnConnectEvent;
      oServer.OnMessage := oConnection.OnMessageEvent;
      oServer.Active := True;
      WriteLn('sgcWebSockets Server started at ws://127.0.0.1:2001/ws');
      while oServer.Active do
        Sleep(10);
    Finally
      oConnection.Free;
      oServer.Free;
    End;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

TMS Sparkle-Beispiel

program HelloWorldServer;
{$APPTYPE CONSOLE}
uses
  System.SysUtils,
  Sparkle.HttpServer.Context,
  Sparkle.HttpServer.Module,
  Sparkle.HttpSys.Server;
type
  THelloWorldModule = class(THttpServerModule)
    public procedure ProcessRequest(const C: THttpServerContext); override;
  end;
procedure THelloWorldModule.ProcessRequest(const C: THttpServerContext);
begin
  C.Response.StatusCode := 200;
  C.Response.ContentType := 'text/plain';
  C.Response.Close(TEncoding.UTF8.GetBytes('Hello, World!'));
end;
const
  ServerUrl = 'http://127.0.0.1:2001/rest';
var
  Server: THttpSysServer;
begin
  Server := THttpSysServer.Create;
  try
    Server.AddModule(THelloWorldModule.Create(ServerUrl));
    Server.Start;
    WriteLn('Hello World Server started at ' + ServerUrl);
    WriteLn('Press Enter to stop');
    ReadLn;
  finally
    Server.Free;
  end;
end. 

Kompilierte Beispiele

Folge der Anleitung unten, um die Beispiele auszuführen:

1. Führe sgcWSServer als Administrator aus. Damit wird ein WebSocket-Server geöffnet, der auf Port 2001 und dem Endpunkt "/ws" lauscht

2. Führe HelloWorldServer aus. Damit wird ein REST-Server geöffnet, der auf Port 2001 und dem Endpunkt "/rest" lauscht

3. Öffne eine WebSocket-Verbindung zu ws://127.0.0.1:2001/ws. Nach dem Verbinden erhältst du eine Nachricht vom Server, und jede gesendete Nachricht wird automatisch vom Server zurückgegeben.

4. Öffne eine HTTP-Verbindung zu http://127.0.0.1:2001/rest. Eine einfache Antwort vom REST-Server wird angezeigt.